Shlomo Yona yona@cs.technion.ac.il http://yeda.cs.technion.ac.il/~yona/
Today's lecture will cover a lot of small details. We will run through many examples. Instead of trying to remember all the small details, try to focus on the big picture, as you can always check out the details on the freely available perldocs.
Given a list of grades for students, print the grades of each student along with an average.
#!/usr/bin/perl -w
$filename = "grades";
open(GRADES, $filename) or die "Can't open $filename: $!\n";
while ($line = <GRADES>) {
($student,$grade) = split(/\s+/, $line);
$grades{$student} .= $grade . " ";
}
foreach $student (sort keys %grades) {
$scores = 0;
$total = 0;
@grades = split(" ", $grades{$student});
foreach $grade (@grades) {
$total += $grade;
++$scores;
}
$average = $total / $scores;
print "$student: $grades{$student}\tAverage: $average\n";
}
Perl has a rich library of functions. They're the verbs of Perl, the commands that the interpreter runs. You can see a list of all the built-in functions on the perlfunc main page. Almost all functions can be given a list of parameters, which are separated by commas.
The print function is one of the most frequently used parts of Perl. You use it to display things on the screen or to send information to a file. It takes a list of things to output as its parameters.
print "This is a single statement.";
print "Look, ", "a ", "list!";
A Perl program consists of statements, each of which ends with a semicolon. Statements don't need to be on separate lines; there may be multiple statements on one line or a single statement can be split across multiple lines.
print "This is "; print "two statements.\n"; print "But this ",
"is only one statement.\n";
Yesterday we talked about scalars (which can contain numbers or strings).
Now we will get to know arrays and lists.
Arrays are an ordered set of scalars.
Array names begin with @.
You define arrays by listing their contents in parentheses, separated by commas:
@lotto_numbers = (1, 2, 3, 4, 5, 6); # Hey, it could happen.
@months = ("July", "August", "September");
The contents of an array are indexed beginning with 0. (Why not 1? Because. Think of the indices as offsets, that is, the coun of how many array elements come before it. Obviously, the first element in the array has 0 elements before it.)
To retrieve the elements of an array, you replace the @ sign with a $ sign, and follow that with the index position of the element you want. (It begins with a dollar sign because you're getting a scalar value.) You can also modify it in place, just like any other scalar.
@months = ("July", "August", "September");
print $months[0]; # This prints "July".
$months[2] = "Smarch"; # We just renamed September!
If an array doesn't exist, it will be created when you try to assign a value to one of its elements.
$winter_months[0] = "December"; # This implicitly creates @winter_months.
The reason we use the $ sign and not the @ sign is because the value is a scalar value.
The length of an array is given by using the array in scalar context:
@array = qw/Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec/;
$num_elements = @array; # 12
$last_index = $#array; # 11 (remember? arrays begin with the index 0)
Hashes are unordered sets of key-value pairs of scalars.
Each key in a hash has one and only one corresponding value.
The name of a hash begins with a percentage sign, like %parents.
You define hashes by comma-separated pairs of key and value, like so:
%last_day_in_month = ( "July" => 31, "August" => 31, "September" => 30 );
You can fetch any value from a hash by referring to $hashname{key}, or modify it in place just like any other scalar.
print $days_in_month{"September"}; # 30, of course.
$days_in_month{"February"} = 29; # It's a leap year.
If you want to see what keys are in a hash, you can use the keys function with the name of the hash. This returns a list containing all of the keys in the hash. The list isn't always in the same order.
@month_list = keys %last_day_in_month;
The three types of variables have three separate namespaces.
That means that $abacus and @abacus are two different variables, and $abacus[0] (the first element of @abacus) is not the same as $abacus{0} (the value in the hash abacus that has the key 0).
So far, our Perl programs have been a bunch of statements in series. This is OK if you're writing very small programs, but as your needs grow, you'll find it's limiting.
A sub is defined with the sub keyword, and adds a new function to your program's capabilities. When you want to use this new function, you call it by name. For instance, here's a short definition of a sub called boo:
sub boo {
print "Boo!\n";
}
boo(); # Eek!
Whenever you call a sub, any parameters you pass to it are placed in the special array @_.
One value (either a scalar, an array or a hash) can be returned using the return keyword.
sub multiply {
my @ops = @_;
return $ops[0] * $ops[1];
}
for $i (1 .. 10) {
print "$i squared is ", multiply($i, $i), "\n";
}
Why did we use the my keyword? That indicates that the variables are private to that sub, so that any existing value for the @ops array we're using elsewhere in our program won't get overwritten.
You can also use my to set up local variables in a sub without assigning them values right away. This can be useful for loop indexes or temporary variables:
sub annoy {
my ($i, $j);
for $i (1 .. 100) {
$j .= "Is this annoying yet?\n";
}
print $j;
}
If you don't expressly use the return statement, the sub returns the result of the last statement. This implicit return value can sometimes be useful, but it does reduce your program's readability. Remember that you'll read your code many more times than you write it!
The simplest regex is simply a word, or more generally, a string of characters. A regex consisting of a word matches any string that contains that word:
"Hello World" =~ /World/; # matches
In this statement, "World" is a regex and the "//" enclos ing "/World/" tells perl to search a string for a match. The operator "=~" associates the string with the regex match and produces a true value if the regex matched, or false if the regex did not match. In our case, "World" matches the second word in ""Hello World"", so the expres sion is true. This idea has several variations.
Expressions like this are useful in conditionals:
print "It matches\n" if "Hello World" =~ /World/;
The sense of the match can be reversed by using "!~" operator:
print "It doesn't match\n" if "Hello World" !~ /World/;
The literal string in the regex can be replaced by a variable:
$greeting = "World";
print "It matches\n" if "Hello World" =~ /$greeting/;
If you're matching against "$_", the "$_ =~" part can be omitted:
$_ = "Hello World";
print "It matches\n" if /World/;
The "//" default delimiters for a match can be changed to arbitrary delimiters by putting an "'m'" out front:
"Hello World" =~ m!World!; # matches, delimited by '!'
"Hello World" =~ m{World}; # matches, note the matching '{}'
"/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
# '/' becomes an ordinary char
Regexes must match a part of the string exactly in order for the statement to be true:
"Hello World" =~ /world/; # doesn't match, case sensitive
"Hello World" =~ /o W/; # matches, ' ' is an ordinary char
"Hello World" =~ /World /; # doesn't match, no ' ' at end
perl will always match at the earliest possible point in the string:
"Hello World" =~ /o/; # matches 'o' in 'Hello'
"That hat is red" =~ /hat/; # matches 'hat' in 'That'
Not all characters can be used 'as is' in a match. Some characters, called metacharacters, are reserved for use in regex notation. The metacharacters are
{}[]()^$.|*+?\
A metacharacter can be matched by putting a backslash before it:
"2+2=4" =~ /2+2/; # doesn't match, + is a metacharacter
"2+2=4" =~ /2\+2/; # matches, \+ is treated like an ordinary +
'C:\WIN32' =~ /C:\\WIN/; # matches
"/usr/local/bin/perl" =~ /\/usr\/local\/bin\/perl/; # matches
In the last regex, the forward slash "'/'" is also backslashed, because it is used to delimit the regex.
Non-printable ASCII characters are represented by escape sequences.
Common examples are "\t" for a tab, "\n" for a newline, and "\r" for a carriage return. Arbitrary bytes are represented by octal escape sequences, e.g., "\033", or hexadecimal escape sequences, e.g., "\x1B":
"1000\t2000" =~ m(0\t2) # matches
"cat" =~ /\143\x61\x74/ # matches, but a weird way to spell cat
Regexes are treated mostly as double quoted strings, so variable interpolation works:
$foo = 'house';
'cathouse' =~ /cat$foo/; # matches
'housecat' =~ /${foo}cat/; # matches
With all of the regexes above, if the regex matched anywhere in the string, it was considered a match. To specify where it should match, we would use the anchor metacharacters "^" and "$". The anchor "^" means match at the beginning of the string and the anchor "$" means match at the end of the string, or before a newline at the end of the string.
Some examples:
"housekeeper" =~ /keeper/; # matches
"housekeeper" =~ /^keeper/; # doesn't match
"housekeeper" =~ /keeper$/; # matches
"housekeeper\n" =~ /keeper$/; # matches
"housekeeper" =~ /^housekeeper$/; # matches
/cat/; # matches 'cat'
/[bcr]at/; # matches 'bat', 'cat', or 'rat'
"abc" =~ /[cab]/; # matches 'a'
/[yY][eE][sS]/; # match 'yes' in a case-insensitive way
# 'yes', 'Yes', 'YES', etc.
/yes/i; # also match 'yes' in a case-insensitive way
/[\]c]def/; # matches ']def' or 'cdef'
$x = 'bcr';
/[$x]at/; # matches 'bat, 'cat', or 'rat'
/[\$x]at/; # matches '$at' or 'xat'
/[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
The special character "'-'" acts as a range operator within character classes, so that the unwieldy "[0123456789]" and "[abc...xyz]" become the svelte "[0-9]" and "[a-z]":
/item[0-9]/; # matches 'item0' or ... or 'item9'
/[0-9a-fA-F]/; # matches a hexadecimal digit
If "'-'" is the first or last character in a character class, it is treated as an ordinary character.
/[^a]at/; # doesn't match 'aat' or 'at', but matches
# all other 'bat', 'cat, '0at', '%at', etc.
/[^0-9]/; # matches a non-numeric character
/[a^]at/; # matches 'aat' or '^at'; here '^' is ordinary
The word anchor "\b" matches a boundary between a word character and a non-word character "\w\W" or "\W\w":
$x = "Housecat catenates house and cat";
$x =~ /\bcat/; # matches cat in 'catenates'
$x =~ /cat\b/; # matches cat in 'housecat'
$x =~ /\bcat\b/; # matches 'cat' at end of string
In the last example, the end of the string is considered a word boundary.
We can match match different character strings with the alternation metacharacter "'|'". To match "dog" or "cat", we form the regex "dog|cat".
As before, perl will try to match the regex at the earliest possible point in the string. At each character position, perl will first try to match the the first alternative, "dog". If "dog" doesn't match, perl will then try the next alternative, "cat". If "cat" doesn't match either, then the match fails and perl moves to the next position in the string.
"cats and dogs" =~ /cat|dog|bird/; # matches "cat"
"cats and dogs" =~ /dog|cat|bird/; # matches "cat"
Even though "dog" is the first alternative in the second regex, "cat" is able to match earlier in the string.
"cats" =~ /c|ca|cat|cats/; # matches "c"
"cats" =~ /cats|cat|ca|c/; # matches "cats"
At a given character position, the first alternative that allows the regex match to succeed wil be the one that matches. Here, all the alternatives match at the first string position, so th first matches.
The grouping metacharacters "()" allow a part of a regex to be treated as a single unit. Parts of a regex are grouped by enclosing them in parentheses. The regex "house(cat|keeper)" means match "house" followed by either "cat" or "keeper".
/(a|b)b/; # matches 'ab' or 'bb'
/(^a|b)c/; # matches 'ac' at start of string or 'bc' anywhere
/house(cat|)/; # matches either 'housecat' or 'house'
/house(cat(s|)|)/; # matches either 'housecats' or 'housecat' or
# 'house'. Note groups can be nested.
"20" =~ /(19|20|)\d\d/; # matches the null alternative '()\d\d',
# because '20\d\d' can't match
The grouping metacharacters "()" also allow the extraction of the parts of a string that matched. For each grouping, the part that matched inside goes into the special variables "$1", "$2", etc. They can be used just as ordinary variables:
# extract hours, minutes, seconds
$time =~ /(\d\d):(\d\d):(\d\d)/; # match hh:mm:ss format
$hours = $1;
$minutes = $2;
$seconds = $3;
In list context, a match "/regex/" with groupings will return the list of matched values "($1,$2,...)". So we could rewrite it as
($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
If the groupings in a regex are nested, "$1" gets the group with the leftmost opening parenthesis, "$2" the next opening parenthesis, etc.
Associated with the matching variables "$1", "$2", ... are the backreferences "\1", "\2", ... Backreferences are matching variables that can be used inside a regex:
/(\w\w\w)\s\1/; # find sequences like 'the the' in string
"$1", "$2", ... should only be used outside of a regex, and "\1", "\2", ... only inside a regex.
The quantifier metacharacters "?", "*", "+", and "{}" allow us to determine the number of repeats of a portion of a regex we consider to be a match. Quantifiers are put immediately after the character, character class, or grouping that we want to specify. They have the following meanings:
/[a-z]+\s+\d*/; # match a lowercase word, at least some space, and
# any number of digits
/(\w+)\s+\1/; # match doubled words of arbitrary length
$year =~ /\d{2,4}/; # make sure year is at least 2 but not more
# than 4 digits
$year =~ /\d{4}|\d{2}/; # better match; throw out 3 digit dates
These quantifiers will try to match as much of the string as possible, while still allowing the regex to match. So we have
$x = 'the cat in the hat'; $x =~ /^(.*)(at)(.*)$/; # matches, # $1 = 'the cat in the h' # $2 = 'at' # $3 = '' (0 matches)
The first quantifier ".*" grabs as much of the string as possible while still having the regex match. The second quantifier ".*" has no string left to it, so it matches 0 times.
Search and replace is performed using "s/regex/replace ment/modifiers". The "replacement" is a Perl double quoted string that replaces in the string whatever is matched with the "regex". The operator "=~" is also used here to associate a string with "s///". If matching against "$_", the "$_ =~" can be dropped. If there is a match, "s///" returns the number of substitutions made, otherwise it returns false.
$x = "Time to feed the cat!";
$x =~ s/cat/hacker/; # $x contains "Time to feed the hacker!"
$y = "'quoted words'";
$y =~ s/^'(.*)'$/$1/; # strip single quotes,
# $y contains "quoted words"
With the "s///" operator, the matched variables "$1", "$2", etc. are immediately available for use in the replacement expression. With the global modifier, "s///g" will search and replace all occurrences of the regex in the string:
$x = "I batted 4 for 4";
$x =~ s/4/four/; # $x contains "I batted four for 4"
$x = "I batted 4 for 4";
$x =~ s/4/four/g; # $x contains "I batted four for four"
The evaluation modifier "s///e" wraps an "eval{...}" around the replacement string and the evaluated result is substituted for the matched substring.
# reverse all the words in a string
$x = "the cat in the hat";
$x =~ s/(\w+)/reverse $1/ge; # $x contains "eht tac ni eht tah"
# convert percentage to decimal
$x = "A 39% hit rate";
$x =~ s!(\d+)%!$1/100!e; # $x contains "A 0.39 hit rate"
The last example shows that "s///" can use other delimiters, such as "s!!!" and "s{}{}", and even "s{}//". If single quotes are used "s'''", then the regex and replacement are treated as single quoted strings.
"split /regex/, string" splits "string" into a list of substrings and returns that list. The regex determines the character sequence that "string" is split with respect to. For example, to split a string into words, use
$x = "Calvin and Hobbes";
@word = split /\s+/, $x; # $word[0] = 'Calvin'
# $word[1] = 'and'
# $word[2] = 'Hobbes'
To extract a comma-delimited list of numbers, use
$x = "1.618,2.718, 3.142";
@const = split /,\s*/, $x; # $const[0] = '1.618'
# $const[1] = '2.718'
# $const[2] = '3.142'
If the empty regex "//" is used, the string is split into individual characters. If the regex has groupings, then list produced contains the matched substrings from the groupings as well:
$x = "/usr/bin";
@parts = split m!(/)!, $x; # $parts[0] = ''
# $parts[1] = '/'
# $parts[2] = 'usr'
# $parts[3] = '/'
# $parts[4] = 'bin'
Since the first character of $x matched the regex, "split" prepended an empty initial element to the list.